// FILENAME: ifs.mod - Benchmark model
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%  
%                       Harold P.E. Ngalawa                               %
%                                                                         %  
%                       School of Economics                               %
%                     University of Cape Town                             %
%                        September 15, 2009                               %
%                                                                         %
%  Title: Interaction of Formal and informal Financial Markets in         % 
%         in Quasi-Emerging Market Economies                              %
%-------------------------------------------------------------------------%

%--------------------------------------------------------------------------
% 0. Housekeeping (close graphics windows)
%--------------------------------------------------------------------------

close all;

%--------------------------------------------------------------------------
% 1. Set simulation periods                                 
%--------------------------------------------------------------------------

periods 500;

%--------------------------------------------------------------------------
% 2. Define variables
% Endogenous (var) and exogenous (varexo)
%--------------------------------------------------------------------------

var A C epie K Lf Li M N P Rrr Rdf Rlf Rli Rnr varpi W Y;

//A     : Technology factor
//C     : Consumption
//epie  : expected inflation
//K     : Capital stock
//Lf    : Formal financial sector loans
//Li    : Informal financial sector loans
//M     : Money supply
//N     : Labour supply/demand
//P     : Price level
//Rrr   : Real interest rates
//Rdf   : Commercial bank deposit rates
//Rlf   : Commercial bank base lending rates
//Rli   : Informal financial sector lending rates
//Rnr   : Bank rate
//varpi : Proportion of aggregate demand for FFS loans that succeeeds in getting the FFS loans
//W     : Wage rate
//Y     : Output

varexo eA mu;

//ea    : Technology shock
//mu    : Monetary policy shock

%--------------------------------------------------------------------------
% 3. Define parameters and assign parameter values 
%--------------------------------------------------------------------------

parameters alpha beta delta eta gamma kyu phi psi rho vah val zeta chi1 chi2;

%--------------------------------------------------------------------------
% 4. Calibration
%--------------------------------------------------------------------------

alpha = 0.37; //Share of capital in production function //values: 0.39 and below
beta = 0.99; //discount rate
delta = 1;  //depreciation
eta = 0.91;  //autoregressive parameter shock 
phi = 3;  //leisure parameter

gamma = 1; //consumption parameter
kyu = 0.85; //Probability of IFS loan repayment
psi = 0.8; //lagrangian multiplier
rho = 0.15; //proportion of high risk borrowers
vah = 0.00001; //risk factor for high risk borrowers (substitution factor of FFSL and IFSL)
val = 0.98;  //success factor for low risk individuals
zeta = 0.1; //mark-up over the bank rate to obtain base lending rates
chi1 = 0.99; //factor of inertia in the base lending rates
chi2 = 0.99; //weight of expected change in output in the monetary policy rule

%--------------------------------------------------------------------------
% 5. Model
%--------------------------------------------------------------------------

model;

 1/C = beta*(1+Rdf)*(1/C(+1));  //1-Intertemporal consumption function

 N = 1-((phi*C)/W);  //2-Labour supply equation 

 M = P*gamma*beta*((C(+1))/Rdf);  //3-Money demand function

 1 + Rdf = (1 + Rli)*kyu;  //4-

 K = ((rho*vah(-1))+((1-rho)*val(-1)))*(Lf(-1)+Li(-1));  //5-Aggregate capital stock equation

 Y = exp(A)*(K^alpha)*(N^(1-alpha));  //6-production function

 A = eta*A(-1) + eA;  //7-Equation describing evolution of technology factor 

 W =(1-alpha)*psi*(Y/N);  //8-Wage equation

 Lf = (varpi/vah)*((((1-alpha)*(1+Rlf)*(K(+1)^alpha))/
      (alpha*vah*W(+1)*N(+1)))^(1/(alpha-1)));  //9-FFS loans supply

 Li = (2-varpi)*(((rho/vah)*((1/vah)^(1/(alpha-1))))+
      (((1-rho)/val)*((1/val)^(1/(alpha-1)))))*
      ((((1-alpha)*(1+Rli)*kyu*(K(+1)^alpha))/(alpha*W(+1)*N(+1)))^(1/(alpha-1)));
      //10-IFS loans supply

 varpi*Rlf = Rnr;  //11-Proportion of demand for FFS loans that succeeds in getting loans
 
 Rlf = Rnr + zeta;  //12-Base Lending Rate
  
 Rrr = alpha*exp(A(+1))*(K(+1)^(alpha-1))*(N(+1)^(1-alpha));  //13-Real interest rate
 
 Y = C + K(+1)-(1-delta)*K;  //14-income accounting identity
 
 Rnr = chi1*Rrr+chi2*(Y(+1)-Y)+(1-chi2)*epie+mu;  //15-monetary policy rule

 epie=Rnr(+1)-Rrr(+1);  //16-Expected inflation

 P*C = M;  //17-Ex-post equilibrium
 
end;

initval;

C = 0.8;
epie = 0.27;
K = 0.2;
N = 0.3;  
Rdf = 0.075;
varpi = 0.7;
W = 0.3;
eA = 0.02;
mu = 0.02;

end;

shocks;
 var eA; stderr 0.25;
 var mu; stderr 0.25;
end;

check;

steady;

stoch_simul(hp_filter = 1600, order = 1, IRF=40);