How to write loops in a Dynare *.mod file

Requires a Dynare version newer than Feb 05, 2008

It is in general much better to write a loop in a *.mod file, for example to analyse different values for a parameter, rather than to call Dynare in a loop

Exemple 1: stoch_simul in a loop over different values for a parameter

Here is an example (from Example 1 in Collard's Practical Guide)

var y, c, k, a, h, b;
varexo e,u;

parameters beta, rho, alpha, delta, theta, psi, tau, phi;

alpha = 0.36;
rho   = 0.95;
tau   = 0.025;
beta  = 0.99;
delta = 0.025;
psi   = 0;
theta = 2.95;

phi   = 0.1;

model;
c*theta*h^(1+psi)=(1-alpha)*y;
k = beta*(((exp(b)*c)/(exp(b(+1))*c(+1)))
    *(exp(b(+1))*alpha*y(+1)+(1-delta)*k));
y = exp(a)*(k(-1)^alpha)*(h^(1-alpha));
k = exp(b)*(y-c)+(1-delta)*k(-1);
a = rho*a(-1)+tau*b(-1) + e;
b = tau*a(-1)+rho*b(-1) + u;
end;

initval;
y = 1.08068253095672;
c = 0.80359242014163;
h = 0.29175631001732;
k = 5;
a = 0;
b = 0;
e = 0;
u = 0;
end;

shocks;
var e; stderr 0.009;
var u; stderr 0.009;
var e, u = phi*0.009*0.009;
end;

rhos = 0.8:0.05:1.05;
for i=1:length(rhos);
 rho = rhos(i);
 stoch_simul(order=1);
 if info;
   disp(['Computation fails for rho = ' num2str(rho)]);
 end;
 // results can be saved here
end;

We want to study the model for the following values of rho=0.8, 0.85, 0.9, 0.95, 1.00, 1.05
At each iteration the model parameter rho takes the appropriate value out of the vector rhos
For rho >= 1, the model doesn't have a stable solution. This condition is recorded in variable info, set by stoch_simul. Testing for info ~= 0 let us take appropriate action if stoch_simul fails

Additional Details

In version 4, it isn't possible to use a parameter as a loop index (used to work in version 3). Don't write

gam_values = [0.1 0.5 0.6];
for gam = gam_values;
  ...

but

gam_values = [0.1 0.5 0.6];
for i = 1:length(gam_values);
  gam = gam_values(i);
  ...