// Test the “filter_tunes” block

var m P c e W R k d n l gy_obs gp_obs y dA;
varexo e_a e_m e_W;

parameters alp bet gam mst rho psi del;

alp = 0.33;
bet = 0.99;
gam = 0.003;
mst = 1.011;
rho = 0.7;
psi = 0.787;
del = 0.02;

model;
dA = exp(gam+e_a);
log(m) = (1-rho)*log(mst) + rho*log(m(-1))+e_m;
-P/(c(+1)*P(+1)*m)+bet*P(+1)*(alp*exp(-alp*(gam+log(e(+1))))*k^(alp-1)*n(+1)^(1-alp)+(1-del)*exp(-(gam+log(e(+1)))))/(c(+2)*P(+2)*m(+1))=0;
W = l/n + e_W;
-(psi/(1-psi))*(c*P/(1-n))+l/n = 0;
R = P*(1-alp)*exp(-alp*(gam+e_a))*k(-1)^alp*n^(-alp)/W;
1/(c*P)-bet*P*(1-alp)*exp(-alp*(gam+e_a))*k(-1)^alp*n^(1-alp)/(m*l*c(+1)*P(+1)) = 0;
c+k = exp(-alp*(gam+e_a))*k(-1)^alp*n^(1-alp)+(1-del)*exp(-(gam+e_a))*k(-1);
P*c = m;
m-1+d = l;
e = exp(e_a);
y = k(-1)^alp*n^(1-alp)*exp(-alp*(gam+e_a));
gy_obs = dA*y/y(-1);
gp_obs = (P/P(-1))*m(-1)/dA;
end;

initval;
k = 6;
m = mst;
P = 2.25;
c = 0.45;
e = 1;
W = 4;
R = 1.02;
d = 0.85;
n = 0.19;
l = 0.86;
y = 0.6;
gy_obs = exp(gam);
gp_obs = exp(-gam);
dA = exp(gam);
end;

steady;

shocks;
  var e_a; stderr 0.014;
  var e_m; stderr 0.005;
  var e_W; stderr 0.001;
end;

varobs gp_obs gy_obs;

filter_tunes;
  var W;
  periods 1, 4:5;
  values 3.5, 3.75;

  var c;
  periods 2;
  values 0.5;
  stderr 0.01;
end;

calib_smoother(datafile=fsdat_simul, nobs=192) y;

// Compare with the by-hand tunes in fs2000_filter_tunes_base.mod
temp = load('fs2000_filter_tunes_base.mat');
tol = 1e-14;
assert(max(abs(oo_.SmoothedVariables.W - temp.oo_.SmoothedVariables.W)) < tol)
assert(max(abs(oo_.SmoothedVariables.c - temp.oo_.SmoothedVariables.c)) < tol)
